# Barebox: am335x
# Contributor: Denis Carikli <GNUtoo@cyberdimension.org>

_pkgname=barebox
pkgname=barebox-am335x
pkgver=2019.01.0
pkgrel=1
pkgdesc="Barebox for devices with an am335x system on a chip"
arch=('armv7h')
makedepends=('lzop')
url="http://barebox.org/"
license=('GPL2')
install=${_pkgname}.install
source=("http://barebox.org/download/${_pkgname}-${pkgver}.tar.bz2")
sha512sums=('34ab54fab52662ef5895b01803fbedb94ed5f0bf399e8bce365f8a9a0205f814d763b80bf96e789df62c3a89d8724af20b9b03e9b2964524cf359b3393edffa1')

build() {
  cd ${_pkgname}-${pkgver}
  unset CFLAGS CXXFLAGS LDFLAGS

  if [ "$CARCH" = "armv7h" ]; then
    export ARCH=arm
    make am335x_mlo_defconfig
    make

    make am335x_defconfig
    make
    # TODO: Add support for more ARM SOCs and
    # CPU architectures (Barebox also supports
    # x86 and PowerPC)
  fi
}

package() {
  cd ${_pkgname}-${pkgver}
  mkdir -p "${pkgdir}/boot/barebox/images/"
  install -t "${pkgdir}/boot/barebox/images/" images/barebox-*.img
}