# Maintainer (Arch): Antonio Rojas <arojas@archlinux.org>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Márcio Silva <coadde@parabola.nu>

pkgname=akonadi-contacts
pkgver=16.12.2
pkgrel=1.parabola1
pkgdesc="Libraries and daemons to implement Contact Management in Akonadi, without nonfree qt5-webengine support"
arch=(i686 x86_64)
url="https://community.kde.org/KDE_PIM"
license=(LGPL)
depends=(akonadi grantlee kcontacts kmime prison)
makedepends=(extra-cmake-modules kdoctools python boost akonadi-mime kcalcore kdesignerplugin)
conflicts=(akonadi-contact)
replaces=(akonadi-contact)
source=("https://download.kde.org/stable/applications/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig}
        'libre.patch')
md5sums=('7bcf579cb3e0373e04d26074a6fbba3a'
         'SKIP'
         'c986a067a638aa0c500cb7662441e2ab')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7) # Albert Astals Cid <aacid@kde.org>

prepare() {
  mkdir -p build
  cd $srcdir/$pkgname-$pkgver
  rm -rv src/editor/addresseditor/webengine
  patch -p1 -i ../libre.patch
}

build() {
  cd build
  cmake ../$pkgname-$pkgver \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DKDE_INSTALL_LIBDIR=lib \
    -DBUILD_TESTING=OFF
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
}