# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Márcio Silva <coadde@parabola.nu>

pkgbase=mesa
_pkgname=libcl
pkgname=lib32-$pkgbase-$_pkgname
_pkgflag=libre
pkgver=10.2.7
pkgrel=2
pkgdesc='Mesa 3-D OpenCL library (32-bit)'
url=http://${pkgbase}3d.sourceforge.net
license=(
  custom
)
arch=(
  x86_64
)
depends=(
  lib32-libclc
  lib32-$pkgbase
)
optdepends=(
  'opencl-headers: headers necessary for OpenCL development'
)
makedepends=(
  # please use libretools, install "multilib-devel" on chroot and add 
  #  "CHROOTEXTRAPKG=(multilib-devel)" on "/etc/libretools.d/chroot.conf" file.
  lib32-clang
  dri2proto
  dri3proto
  glproto
  imake
  lib32-libxml2
  presentproto
  python2
  lib32-libvdpau
)
provides=(
  lib32-$_pkgname-$_pkgflag
  lib32-$_pkgname
  lib32-opencl-nvidia
  lib32-opencl-nvidia-304xx
  lib32-opencl-$pkgbase
)
conflicts=(
  lib32-$_pkgname-$_pkgflag
  lib32-$_pkgname
  lib32-opencl-nvidia
  lib32-opencl-nvidia-304xx
  lib32-opencl-$pkgbase
)
replaces=(
  lib32-$_pkgname-$_pkgflag
  lib32-$_pkgname
  lib32-opencl-nvidia
  lib32-opencl-nvidia-304xx
  lib32-opencl-$pkgbase
)
source=(
  ftp://ftp.freedesktop.org/pub/$pkgbase/${pkgver%.0}/${pkgbase^}Lib-$pkgver.tar.bz2
  llvm35.patch
)
sha512sums=(
  c6d346499ef9596d3b5cd0bdc0ec64b58e8170203e0c977c54b55652c8792beb471822c101461745f7228a7d15a43924211f56fc0cc989defdc1acc4ea7b8a71
  dbf6792c94c80e067f3d1a33237ca1e28be7069a366c46b36997afab97c8a712758b07dc7f9fce0b3e20b8280d41539f02d70ee5c7e16188d8f6db9731fb6881
)

prepare() {
  cd $srcdir/${pkgbase^}-$pkgver
  patch -Np1 -i ../llvm35.patch
}

build() {
  cd $srcdir/${pkgbase^}-$pkgver
  export CC="gcc -m32"
  export CXX="g++ -m32"
  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
  export LLVM_CONFIG=/usr/bin/llvm-config32
  autoreconf -vfi
  ./configure --prefix=/usr --libdir=/usr/lib32 --enable-32-bit\
    --enable-opencl\
    --enable-gallium-llvm\
    --enable-r600-llvm-compiler\
    --enable-dri3\
    --with-clang-libdir=/usr/lib\
    --enable-llvm-shared-libs\
    --with-gallium-drivers=i915,nouveau,r300,r600,radeonsi,svga,swrast
  make
}

package() {
  cd $srcdir/${pkgbase^}-$pkgver
  make -C src/gallium/targets/opencl DESTDIR=$pkgdir install
  install -vdm755 $pkgdir/usr/share/licenses/$pkgname
  install -vm644 docs/COPYING      $pkgdir/usr/share/licenses/$pkgname
  install -vm644 docs/license.html $pkgdir/usr/share/licenses/$pkgname/LICENSE
}