# Maintainer (Arch): PitBall
# Maintainer: André Silva <emulatorman@parabola.nu>
# Maintainer: Márcio Silva <coadde@parabola.nu>

pkgname=lib32-clang
pkgver=3.5.0
pkgrel=2
pkgdesc="C language family frontend for LLVM (32-bit)"
arch=('x86_64')
url="http://clang.llvm.org/"
license=('custom:University of Illinois/NCSA Open Source License')
depends=('clang' 'lib32-llvm' 'gcc-multilib')
# please use libretools, install "multilib-devel" on chroot and add
#  "CHROOTEXTRAPKG=(multilib-devel)" on "/etc/libretools.d/chroot.conf" file.
makedepends=('lib32-libffi' 'lib32-zlib' 'python2')
options=('staticlibs')
source=(http://llvm.org/releases/$pkgver/llvm-$pkgver.src.tar.xz{,.sig}
        http://llvm.org/releases/$pkgver/cfe-$pkgver.src.tar.xz{,.sig}
        http://llvm.org/releases/$pkgver/compiler-rt-$pkgver.src.tar.xz{,.sig}
        llvm-3.5.0-force-link-pass.o.patch)
sha256sums=('28e199f368ef0a4666708f31c7991ad3bcc3a578342b0306526dd35f07595c03'
            'SKIP'
            'fc80992e004b06f6c7afb612de1cdaa9ac9d25811c55f94fcf7331d9b81cdb8b'
            'SKIP'
            'a4b3e655832bf8d9a357ea2c771db347237460e131988cbb96cda40ff39a8136'
            'SKIP'
            '5702053503d49448598eda1b8dc8c263f0df9ad7486833273e3987b5dec25a19')

prepare() {
  cd "$srcdir/llvm-$pkgver.src"

  # At the present, clang must reside inside the LLVM source code tree to build
  # See http://llvm.org/bugs/show_bug.cgi?id=4840
  mv "$srcdir/cfe-$pkgver.src" tools/clang

  mv "$srcdir/compiler-rt-$pkgver.src" projects/compiler-rt

  # Fix installation directories, ./configure doesn't seem to set them right
  sed -i 's:\$(PROJ_prefix)/lib:$(PROJ_prefix)/lib32:' \
    Makefile.config.in
  sed -i '/ActiveLibDir = ActivePrefix/s:lib:lib32:' \
    tools/llvm-config/llvm-config.cpp
  sed -i 's:LLVM_LIBDIR="${prefix}/lib":LLVM_LIBDIR="${prefix}/lib32":' \
    autoconf/configure.ac \
    configure

  # Fix build with GCC 4.9 (patch from Debian)
  # http://llvm.org/bugs/show_bug.cgi?id=20067
  patch -Np1 -i "$srcdir/llvm-3.5.0-force-link-pass.o.patch"
}

build() {
  cd $srcdir/llvm-$pkgver.src

  export CC='gcc -m32'
  export CXX='g++ -m32'
  export PKG_CONFIG_PATH=/usr/lib32/pkgconfig

  # Apply strip option to configure
  _optimized_switch=enable
  [[ $(check_option strip) == n ]] && _optimized_switch=disable

  # Include location of libffi headers in CPPFLAGS
  CPPFLAGS+=" $(pkg-config --cflags libffi)"

  # We had to force host and target to get
  # a proper triplet reported by llvm

  ./configure \
    --prefix=/usr \
    --libdir=/usr/lib32 \
    --sysconfdir=/etc \
    --enable-shared \
    --enable-libffi \
    --enable-targets=all \
    --disable-expensive-checks \
    --disable-debug-runtime \
    --disable-assertions \
    --with-binutils-include=/usr/include \
    --with-python=/usr/bin/python2 \
    --build=i686-pc-linux-gnu \
    --host=i686-pc-linux-gnu \
    --$_optimized_switch-optimized

  make REQUIRES_RTTI=1
}

package() {
  cd $srcdir/llvm-$pkgver.src/tools/clang

  make -C lib DESTDIR=$pkgdir install

  # fix include dir on lib32 dir
  rm -rv $pkgdir/usr/lib
  ln -s /usr/lib/clang $pkgdir/usr/lib32/clang

  # Fix permissions of static libs
  chmod -x $pkgdir/usr/lib32/*.a

  install -Dm644 LICENSE.TXT "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

# vim:set ts=2 sw=2 et: