# $Id: $
# Maintainer: André Silva <emulatorman@lavabit.com>

pkgname=linux-libre-lts-api-headers
_basekernel=3.0
_sublevel=44
pkgver=${_basekernel}.${_sublevel}
pkgrel=1
pkgdesc="Kernel libre lts headers sanitized for use in userspace - stable longtime supported kernel package suitable for servers"
arch=('i686' 'x86_64' 'mips64el')
url="http://www.gnu.org/software/libc"
license=('GPL2')
provides=("linux-api-headers=3.5" "linux-libre-api-headers=3.5")
conflicts=('linux-api-headers' 'linux-libre-api-headers')
replaces=('linux-api-headers' 'linux-libre-api-headers')
source=("http://linux-libre.fsfla.org/pub/linux-libre/releases/${_basekernel}-gnu/linux-libre-${_basekernel}-gnu.tar.xz"
        "http://linux-libre.fsfla.org/pub/linux-libre/releases/${pkgver}-gnu/patch-${_basekernel}-gnu-${pkgver}-gnu.xz")
md5sums=('5f64180fe7df4e574dac5911b78f5067'
         '6daa8be01b49423178082ebf5f615a24')

build() {
  cd ${srcdir}/linux-${_basekernel}

  if [ "${_basekernel}" != "${pkgver}" ]; then
    patch -Np1 -i "${srcdir}/patch-${_basekernel}-gnu-${pkgver}-gnu"
  fi

  make mrproper
  make headers_check
}

package() {
  cd ${srcdir}/linux-${_basekernel}
  make INSTALL_HDR_PATH=${pkgdir}/usr headers_install

  # use headers from libdrm
  rm -rf ${pkgdir}/usr/include/drm
  
  # clean-up unnecessary files generated during install
  find ${pkgdir} \( -name .install -o -name ..install.cmd \) -delete
}