From 41c85d2f4b0724df0a4252b2ca10faa91bb77d43 Mon Sep 17 00:00:00 2001
From: André Fabian Silva Delgado <emulatorman@parabola.nu>
Date: Wed, 8 Mar 2017 12:57:22 -0300
Subject: tekdefense-automater-git: minor fix

---
 pcr/tekdefense-automater-git/PKGBUILD | 58 +++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 pcr/tekdefense-automater-git/PKGBUILD

(limited to 'pcr/tekdefense-automater-git/PKGBUILD')

diff --git a/pcr/tekdefense-automater-git/PKGBUILD b/pcr/tekdefense-automater-git/PKGBUILD
new file mode 100644
index 000000000..dea367576
--- /dev/null
+++ b/pcr/tekdefense-automater-git/PKGBUILD
@@ -0,0 +1,58 @@
+# Maintainer: Márcio Silva <coadde@parabola.nu>
+# Contributor: André Silva <emulatorman@parabola.nu>
+
+_pkgname='tekdefense-automater'
+pkgname='tekdefense-automater-git'
+pkgver=88.42548cf
+pkgrel=3
+pkgdesc='IP URL and MD5 OSINT Analysis'
+arch=('any')
+url='https://github.com/1aN0rmus/TekDefense-Automater'
+license=('MIT')
+replaces=("$_pkgname")
+conflicts=("$_pkgname")
+provides=("$_pkgname")
+depends=('python2')
+makedepends=('git')
+source=('git+https://github.com/1aN0rmus/TekDefense-Automater.git')
+sha1sums=('SKIP')
+
+pkgver() {
+  cd "$srcdir/TekDefense-Automater"
+
+  echo $(git rev-list --count HEAD).$(git rev-parse --short HEAD)
+}
+
+prepare() {
+  cd "$srcdir/TekDefense-Automater"
+
+  sed -i 's|/usr/bin/python|/usr/bin/python2|g' Automater.py
+}
+
+package() {
+  cd "$srcdir/TekDefense-Automater"
+
+  mkdir -p "$pkgdir/usr/bin"
+  mkdir -p "$pkgdir/usr/share/tekdefense-automater"
+
+  for f in *.py
+  do
+    install -m644 $f "$pkgdir/usr/share/tekdefense-automater/$f"
+  done
+
+  install -Dm644 -t "$pkgdir/usr/share/tekdefense-automater/" *.xml
+  install -Dm644 "LICENSE" \
+    "$pkgdir/usr/share/licenses/tekdefense-automater/LICENSE"
+  install -Dm644 "README.md" \
+    "$pkgdir/usr/share/doc/tekdefense-automater/README.md"
+
+  cp -a docs/* "$pkgdir/usr/share/doc/tekdefense-automater"
+
+  cat > "$pkgdir/usr/bin/automater" << EOF
+#!/bin/sh
+cd /usr/share/tekdefense-automater
+exec python2 Automater.py "\$@"
+EOF
+
+  chmod +x "$pkgdir/usr/bin/automater"
+}
-- 
cgit v1.2.3