From af6a93922eb42bb02fee64165e4e5ab8d69966b9 Mon Sep 17 00:00:00 2001
From: Denis 'GNUtoo' Carikli <GNUtoo@cyberdimension.org>
Date: Fri, 28 Dec 2018 11:37:36 +0100
Subject: move xtrx related packages from pcr-testing to pcr

The pakcages have been tested and work on x86_64.

I successfully received commercial FM radio stations
with it with the following settings:

I/O devices configuration:
--------------------------
Device: other
Device String: xtrx
Input Rate: 5000000
Decimation: None
Sample rate: 5Msps
Banwith: 1.000000 MHz
LNO LB:  0.000000 Mhz

Input control:
--------------
LNA gain: 22 db
TIA gain:  9 db
PGA gain: 12 db
 LB gain:  0 db
Swap I/Q   []
DC Remove  []
No limits  []
IQ balance []
Freq. correction: 0.0 ppm
Antenna: RXL
Reset frequency controller digits []

Note that the chosen Antenna is specific to my setup.

TODO:
- Make the package install in /usr/ instead of /usr/local
- Validate the packages on i686 and armv7h
- Package the kernel module
- Package the other libraries required for the USB3 support.

Signed-off-by: Denis 'GNUtoo' Carikli <GNUtoo@cyberdimension.org>
---
 pcr/gnuradio-osmosdr-xtrx/PKGBUILD | 45 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)
 create mode 100644 pcr/gnuradio-osmosdr-xtrx/PKGBUILD

(limited to 'pcr/gnuradio-osmosdr-xtrx/PKGBUILD')

diff --git a/pcr/gnuradio-osmosdr-xtrx/PKGBUILD b/pcr/gnuradio-osmosdr-xtrx/PKGBUILD
new file mode 100644
index 000000000..5fbcaa54a
--- /dev/null
+++ b/pcr/gnuradio-osmosdr-xtrx/PKGBUILD
@@ -0,0 +1,45 @@
+# $Id$
+# Maintainer: Kyle Keen <keenerd@gmail.com?>
+# Contributor: Dominik Heidler <dheidler@gmail.com>
+# Contributor: Denis 'GNUtoo' Carikli <GNUtoo@cyberdimension.org>
+pkgname=gnuradio-osmosdr-xtrx
+_pkgname=gr-osmosdr
+pkgver=0.1.4+git
+pkgrel=26
+pkgdesc="Source block for Funcube Dongle, RTL-SDR, USRP, OsmoSDR, BladeRF, HackRF and AirSpy devices"
+url="http://sdr.osmocom.org/trac/"
+arch=(armv7h i686 x86_64)
+license=('GPL')
+depends=('gnuradio' 'gnuradio-iqbal' 'rtl-sdr' 'gnuradio-fcdproplus' 'hackrf' 'bladerf' 'airspy')
+optdepends=('python2-opengl: osmocom_fft')
+makedepends=('git' 'cmake' 'boost' 'python2-cheetah' 'swig')
+conflicts=('gr-osmosdr-git' 'gnuradio-osmosdr')
+branch=libxtrx
+source=("git://github.com/xtrx-sdr/gr-osmosdr.git#branch=$branch")
+md5sums=('SKIP')
+
+# add support for miri, osmo?
+
+prepare() {
+  cd "$srcdir/$_pkgname"
+  sed -i 's/python$/python2/' apps/osmocom_siggen_base.py
+}
+
+build() {
+  cd "$srcdir/$_pkgname"
+  mkdir build
+  cd build
+  cmake \
+    -Wno-dev \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DPYTHON_EXECUTABLE=$(which python2) \
+    -DPYTHON_INCLUDE_DIR=$(echo /usr/include/python2*) \
+    -DPYTHON_LIBRARY=$(echo /usr/lib/libpython2.*.so) \
+    -DCMAKE_INSTALL_PREFIX=/usr ../
+  make
+}
+
+package() {
+  cd "$srcdir/$_pkgname/build/"
+  make DESTDIR="${pkgdir}" install
+}
-- 
cgit v1.2.3