From 978a2503d46c9a272ee3ac6243f3461e9ba64377 Mon Sep 17 00:00:00 2001
From: Aurelien Desbrieres <aurelien@hackers.camp>
Date: Sun, 8 Mar 2015 12:03:49 +0100
Subject: arduino prototyping platform sdk

---
 pcr/arduino/PKGBUILD | 57 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)
 create mode 100644 pcr/arduino/PKGBUILD

(limited to 'pcr/arduino/PKGBUILD')

diff --git a/pcr/arduino/PKGBUILD b/pcr/arduino/PKGBUILD
new file mode 100644
index 000000000..fd4a0eb20
--- /dev/null
+++ b/pcr/arduino/PKGBUILD
@@ -0,0 +1,57 @@
+# Maintainer : Aurélien Desbrières <aurelien@hackers.camp>
+# Contributor: Niels Martignène <niels.martignene@gmail.com>
+# Contributor: PyroPeter <googlemail.com@abi1789>
+# Contributor: darkapex <me@jailuthra.in>
+# Contributor: tty0 <vt.tty0[d0t]gmail.com>
+
+pkgname=arduino
+epoch=1
+pkgver=1.6.0
+pkgrel=1
+pkgdesc="Arduino prototyping platform SDK"
+arch=('i686' 'x86_64')
+url="http://arduino.cc/en/Main/Software"
+options=(!strip staticlibs)
+license=('GPL' 'LGPL')
+depends=('gtk2' 'libusb-compat' 'java-runtime' 'desktop-file-utils')
+makedepends=('icoutils')
+conflicts=('arduino-toolchain')
+install="arduino.install"
+source=('arduino.desktop'
+        'arduino.xml')
+
+source_i686+=("http://arduino.cc/download_handler.php?f=/arduino-${pkgver}-linux32.tar.xz")
+source_x86_64+=("http://arduino.cc/download_handler.php?f=/arduino-${pkgver}-linux64.tar.xz")
+
+build() {
+  cd "arduino-${pkgver}"
+
+  icotool -x -o .. lib/arduino_icon.ico
+}
+
+package() {
+  cd "arduino-${pkgver}"
+
+  mkdir -p "${pkgdir}/usr/bin"
+  mkdir -p "${pkgdir}/usr/share/"{doc,applications,mime/packages}
+
+  # copy the whole SDK to /usr/share/arduino/
+  cp -a . "${pkgdir}/usr/share/arduino"
+
+  # at least support the FHS a little bit
+  ln -s /usr/share/arduino/arduino "${pkgdir}/usr/bin/arduino"
+  ln -s /usr/share/arduino/reference "${pkgdir}/usr/share/doc/arduino"
+
+  # fix avrdude's broken dependency on libtinfo.so.5
+  ln -s /usr/lib/libncurses.so.5 "${pkgdir}/usr/share/arduino/hardware/tools/avr/lib/libtinfo.so.5"
+
+  # desktop icon
+  for size in 16 32 48 256; do
+    install -Dm644 ../arduino_icon_*_${size}x${size}x32.png \
+      "${pkgdir}/usr/share/icons/hicolor/${size}x${size}/apps/arduino.png"
+  done
+
+  # desktop and mimetype files
+  install -m644 "${srcdir}/arduino.desktop" "${pkgdir}/usr/share/applications/"
+  install -m644 "${srcdir}/arduino.xml" "${pkgdir}/usr/share/mime/packages/"
+}
-- 
cgit v1.2.3