From 289aac35107204dc38a438184c868183905d010d Mon Sep 17 00:00:00 2001
From: André Fabian Silva Delgado <emulatorman@parabola.nu>
Date: Tue, 20 Dec 2016 13:59:05 -0300
Subject: kmail-16.12.0-1.nonprism1: updating version

* remove some kdepim packages from [nonprism] since Google Drive support comes from pim-storage-service-manager now
---
 nonprism/kmail/PKGBUILD | 45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)
 create mode 100644 nonprism/kmail/PKGBUILD

(limited to 'nonprism/kmail/PKGBUILD')

diff --git a/nonprism/kmail/PKGBUILD b/nonprism/kmail/PKGBUILD
new file mode 100644
index 000000000..0939a78e6
--- /dev/null
+++ b/nonprism/kmail/PKGBUILD
@@ -0,0 +1,45 @@
+# Maintainer (Arch): Antonio Rojas <arojas@archlinux.org>
+# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
+# Maintainer: André Silva <emulatorman@parabola.nu>
+
+pkgname=kmail
+pkgver=16.12.0
+pkgrel=1.nonprism1
+pkgdesc="KDE mail client, without pim-storage-service-manager and Phishing Google System support"
+arch=(i686 x86_64)
+url="https://community.kde.org/KDE_PIM"
+license=(GPL2)
+depends=(kdepim-runtime kmail-account-wizard akonadi-import-wizard mbox-importer pim-sieve-editor
+         kontactinterface libktnef)
+makedepends=(extra-cmake-modules kdoctools kdesignerplugin boost python)
+optdepends=('kleopatra: mail encryption support' 'kdepim-addons: additional plugins')
+conflicts=(ktnef)
+replaces=(ktnef)
+groups=(kde-applications kdepim)
+source=("http://download.kde.org/stable/applications/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig}
+        'nonprism.patch')
+md5sums=('63939b64d6990064fd2d37e6450f00f9'
+         'SKIP'
+         'eabc3c4be17fb6275b15cfb4577f8035')
+validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7) # Albert Astals Cid <aacid@kde.org>
+
+prepare() {
+  mkdir -p build
+  cd $pkgname-$pkgver
+  patch -p1 -i ../nonprism.patch
+}
+
+build() {
+  cd build
+  cmake ../$pkgname-$pkgver \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DBUILD_TESTING=OFF
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+}
-- 
cgit v1.2.3