From c0f6f0bc32e3349c840aa1cd915fc12b2a22cc03 Mon Sep 17 00:00:00 2001
From: "coadde [Márcio Alexandre Silva Delgado]" <coadde@parabola.nu>
Date: Tue, 7 Mar 2017 18:31:40 -0300
Subject: tekdefense-automater-88.42548cf-3: available in [pcr]

---
 pcr/tekdefense-automater/PKGBUILD | 53 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 pcr/tekdefense-automater/PKGBUILD

diff --git a/pcr/tekdefense-automater/PKGBUILD b/pcr/tekdefense-automater/PKGBUILD
new file mode 100644
index 000000000..bac6db4c0
--- /dev/null
+++ b/pcr/tekdefense-automater/PKGBUILD
@@ -0,0 +1,53 @@
+# Maintainer: Márcio Silva <coadde@parabola.nu>
+
+pkgname='tekdefense-automater'
+pkgver=88.42548cf
+pkgrel=3
+pkgdesc='IP URL and MD5 OSINT Analysis'
+arch=('any')
+url='https://github.com/1aN0rmus/TekDefense-Automater'
+license=('MIT')
+depends=('python2')
+makedepends=('git')
+source=('git+https://github.com/1aN0rmus/TekDefense-Automater.git')
+sha1sums=('SKIP')
+
+pkgver() {
+  cd "$srcdir/TekDefense-Automater"
+
+  echo $(git rev-list --count HEAD).$(git rev-parse --short HEAD)
+}
+
+prepare() {
+  cd "$srcdir/TekDefense-Automater"
+
+  sed -i 's|/usr/bin/python|/usr/bin/python2|g' Automater.py
+}
+
+package() {
+  cd "$srcdir/TekDefense-Automater"
+
+  mkdir -p "$pkgdir/usr/bin"
+  mkdir -p "$pkgdir/usr/share/tekdefense-automater"
+
+  for f in *.py
+  do
+    install -m644 $f "$pkgdir/usr/share/tekdefense-automater/$f"
+  done
+
+  install -Dm644 -t "$pkgdir/usr/share/tekdefense-automater/" *.xml
+  install -Dm644 "LICENSE" \
+    "$pkgdir/usr/share/licenses/tekdefense-automater/LICENSE"
+  install -Dm644 "README.md" \
+    "$pkgdir/usr/share/doc/tekdefense-automater/README.md"
+
+  cp -a docs/* "$pkgdir/usr/share/doc/tekdefense-automater"
+
+  cat > "$pkgdir/usr/bin/automater" << EOF
+#!/bin/sh
+cd /usr/share/tekdefense-automater
+exec python2 Automater.py "\$@"
+EOF
+
+  chmod +x "$pkgdir/usr/bin/automater"
+}
-- 
cgit v1.2.3