From 153dc511cce2cc48ede8fda749f1d6af0944ab01 Mon Sep 17 00:00:00 2001
From: Luke Shumaker <lukeshu@lukeshu.com>
Date: Wed, 29 Mar 2017 16:33:16 -0400
Subject: re-add ~lukeshu/holo-lukeshu for upgrading purposes

---
 ~lukeshu/holo-lukeshu/PKGBUILD | 52 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)
 create mode 100644 ~lukeshu/holo-lukeshu/PKGBUILD

diff --git a/~lukeshu/holo-lukeshu/PKGBUILD b/~lukeshu/holo-lukeshu/PKGBUILD
new file mode 100644
index 000000000..88bc9ef8c
--- /dev/null
+++ b/~lukeshu/holo-lukeshu/PKGBUILD
@@ -0,0 +1,52 @@
+# Maintainer (AUR): Stefan Majewsky <majewsky@gmx.net>
+# Maintainer: Luke Shumaker <lukeshu@parabola.nu>
+
+# Upstream info
+_pkgname='holo'
+_pkgver=1.2.1
+_pkgdesc='Minimalistic configuration management'
+url='http://holocm.org'
+license=('GPL3')
+
+# patch info
+pkgname=$_pkgname-lukeshu
+pkgver=$_pkgver.lukeshu1
+pkgdesc="$_pkgdesc (with patches from lukeshu)"
+_gitver='commit=6e22b1f69650910f71f9f93d705e973384f3fab8'
+mksource=("$_pkgname-$pkgver::git+https://github.com/lukeshu/holo#$_gitver")
+mkmd5sums=('SKIP')
+provides=("$_pkgname=$pkgver")
+conflicts=("$_pkgname")
+
+# package info
+pkgrel=2
+arch=('i686' 'x86_64' 'armv7h')
+depends=('git')
+makedepends=('go' 'perl')
+provides+=(
+  "holo-files=$pkgver"
+  'HOLO_API_VERSION=3'
+)
+backup=(
+  'etc/holorc'
+  'etc/holorc.d/10-files'
+)
+source=("https://repo.parabola.nu/other/~lukeshu/holo/$_pkgname-$pkgver.tar.gz")
+sha256sums=('0572fcff14fd2a740fce50070475f8d79c96464040f54d12cc7b212f1a5e64fb')
+
+options=('!strip') # binaries are already stripped inside the Makefile
+
+build() {
+  cd "${srcdir}/${_pkgname}-${pkgver}"
+  make
+}
+
+check() {
+  cd "${srcdir}/${_pkgname}-${pkgver}"
+  make check
+}
+
+package() {
+  cd "${srcdir}/${_pkgname}-${pkgver}"
+  make install DESTDIR="${pkgdir}"
+}
-- 
cgit v1.2.3