3 files changed, 114 insertions, 0 deletions
diff --git a/pcr/xombrero/LICENSE b/pcr/xombrero/LICENSE
new file mode 100644
index 000000000..f3cc75ccd
--- /dev/null
+++ b/pcr/xombrero/LICENSE
@@ -0,0 +1,16 @@
+/*
+ * Copyright (c) 2010 Marco Peereboom <marco@peereboom.us>
+ *
+ * Permission to use, copy, modify, and distribute this software for any
+ * purpose with or without fee is hereby granted, provided that the above
+ * copyright notice and this permission notice appear in all copies.
+ *
+ * THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
+ * WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
+ * MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
+ * ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
+ * WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
+ * ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
+ * OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
+ */
+
diff --git a/pcr/xombrero/PKGBUILD b/pcr/xombrero/PKGBUILD
new file mode 100644
index 000000000..d2257a643
--- /dev/null
+++ b/pcr/xombrero/PKGBUILD
@@ -0,0 +1,86 @@
+# Maintainer (Arch): Kyle Keen <keenerd@gmail.com>
+
+pkgbase=xombrero
+#pkgname=('xombrero' 'xombrero3')
+pkgname=xombrero
+#pkgname=xombrero3  # uncomment to package the gtk3 version instead
+pkgver=1.6.3
+pkgrel=2
+pkgdesc="A minimalists web browser, vi-like but with traditional web browser behavior."
+arch=('i686' 'x86_64')
+url="https://opensource.conformal.com/wiki/xombrero"
+_watch="https://opensource.conformal.com/snapshots/xombrero/"
+license=('custom:ISC')
+depends=('webkitgtk2' 'libbsd' 'desktop-file-utils')
+if [[ "$pkgname" == "xombrero3" ]]; then
+    depends=('webkitgtk3' 'libbsd' 'desktop-file-utils')
+fi
+install=$pkgbase.install
+replaces=('xxxterm')
+conflicts=('xxxterm')
+options=('!emptydirs')
+source=(http://opensource.conformal.com/snapshots/$pkgname/$pkgbase-$pkgver.tgz \
+        LICENSE)
+md5sums=('11248a0f40542265022e8dfe692644da'
+         'f3eeb6e8b70a3dcccb8ee57daf584c9e')
+
+build() {
+    cd "$srcdir/$pkgbase-$pkgver"
+    # no spam
+    sed -i 's|https://www.cyphertite.com|https://archlinux.org|' xombrero.{c,conf,h}
+    # relocations
+    sed -i 's|/etc/ssl/cert.pem|/etc/ssl/certs/ca-certificates.crt|' xombrero.conf
+    #sed -i 's|/usr/local/share/xombrero/style.css|/usr/share/xombrero/style.css|' xombrero.conf
+    sed -i 's|/usr/local/share/|/usr/share/|' {unix.c,xombrero.conf,xombrero.h}
+    cd ..
+
+    mkdir -p build-gtk{2,3}
+    if [[ "$pkgname" == "xombrero" ]]; then
+        cp -R "$srcdir/$pkgbase-$pkgver" build-gtk2
+        pushd "build-gtk2/$pkgbase-$pkgver"
+        make PREFIX="/usr" -C linux GTK_VERSION=gtk2
+        popd
+    fi
+
+    if [[ "$pkgname" == "xombrero3" ]]; then
+        cp -R "$srcdir/$pkgbase-$pkgver" build-gtk3
+        pushd "build-gtk3/$pkgbase-$pkgver"
+        make PREFIX="/usr" -C linux GTK_VERSION=gtk3
+        popd
+    fi
+}
+
+# non-split aur compatibility function (remove for real split pkg)
+package() {
+    if [[ "$pkgname" == "xombrero" ]]; then
+        package_xombrero
+    elif [[ "$pkgname" == "xombrero3" ]]; then
+        package_xombrero3
+    fi
+}
+
+package_xombrero() {
+    depends=('webkitgtk2' 'libbsd' 'desktop-file-utils')
+    conflicts=('xxxterm' 'xombrero3')
+
+    cd "$srcdir/build-gtk2/$pkgbase-$pkgver"
+    mkdir -p "$pkgdir/usr/share/applications/"  # buggy makefile
+    make PREFIX="/usr" DESTDIR="$pkgdir" install -C linux GTK_VERSION=gtk2
+    install -Dm644 xombrero.conf     "$pkgdir/etc/skel/.xombrero.conf"
+    install -Dm644 xombrero.desktop  "$pkgdir/usr/share/applications/xombrero.desktop"
+    install -Dm755 config-checker.pl "$pkgdir/usr/bin/config-checker.pl"
+    install -Dm644 "$srcdir/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+package_xombrero3() {
+    depends=('webkitgtk3' 'libbsd' 'desktop-file-utils')
+    conflicts=('xombrero')
+
+    cd "$srcdir/build-gtk3/$pkgbase-$pkgver"
+    mkdir -p "$pkgdir/usr/share/applications/"  # buggy makefile
+    make PREFIX="/usr" DESTDIR="$pkgdir" install -C linux GTK_VERSION=gtk3
+    install -Dm644 xombrero.conf     "$pkgdir/etc/skel/.xombrero.conf"
+    install -Dm644 xombrero.desktop  "$pkgdir/usr/share/applications/xombrero.desktop"
+    install -Dm755 config-checker.pl "$pkgdir/usr/bin/config-checker.pl"
+    install -Dm644 "$srcdir/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
diff --git a/pcr/xombrero/xombrero.install b/pcr/xombrero/xombrero.install
new file mode 100644
index 000000000..d3289ab64
--- /dev/null
+++ b/pcr/xombrero/xombrero.install
@@ -0,0 +1,12 @@
+post_install() {
+  update-desktop-database -q
+}
+
+post_upgrade() {
+  post_install
+}
+
+post_remove() {
+  post_install
+}
+