1 files changed, 44 insertions, 0 deletions
diff --git a/pcr/sacd-ripper/PKGBUILD b/pcr/sacd-ripper/PKGBUILD
new file mode 100644
index 000000000..65ba7b43b
--- /dev/null
+++ b/pcr/sacd-ripper/PKGBUILD
@@ -0,0 +1,44 @@
+# Maintainer: Luke Shumaker <lukeshu@sbcglobal.net>
+
+_pkgbase=sacd-ripper
+pkgname=sacd-extact
+pkgver=0.3.7.git20130822
+_gitver='commit=d2c2441e7aa8be6d7f47f045da770c267b59a547'
+pkgdesc="Super Audio CD extractor"
+url=https://github.com/hank/$_pkgbase/tree/master/tools/sacd_extract
+license=(GPL) # GPLv2+
+
+arch=(i686 x86_64)
+pkgrel=1
+makedepends=(cmake)
+
+source=(https://repo.parabola.nu/other/pcr/$_pkgbase/$_pkgbase-$pkgver.tar.gz
+        sacd-ripper-glibc.patch)
+md5sums=('9d366465a68d1583bb675f57739b413a'
+         'b0b2cf599cbc443608bfc9516e1d35b4')
+
+mksource=("$_pkgbase-$pkgver::git+https://github.com/hank/$_pkgbase.git#${_gitver}")
+mkmd5sums=('SKIP')
+
+prepare() {
+        cd "$srcdir/$_pkgbase-$pkgver"
+        patch -p1 -i ../sacd-ripper-glibc.patch
+}
+
+build() {
+        cd "$srcdir"
+
+        sed -n '/^-- SACD Ripper\/Extract Usage Instructions --/,$p' \
+            < $_pkgbase-$pkgver/readme \
+            > README
+
+        mkdir build
+        cd build
+        cmake ../$_pkgbase-$pkgver/tools/sacd_extract
+        make
+}
+
+package() {
+        install -Dm755 "$srcdir"/build/sacd_extract -t "$pkgdir"/usr/bin
+        install -Dm644 "$srcdir"/README -t "$pkgdir"/usr/share/doc/$pkgname
+}