1 files changed, 34 insertions, 0 deletions
diff --git a/pcr/kiwix-lib/PKGBUILD b/pcr/kiwix-lib/PKGBUILD
new file mode 100644
index 000000000..64d18ec19
--- /dev/null
+++ b/pcr/kiwix-lib/PKGBUILD
@@ -0,0 +1,34 @@
+# Maintainer (AUR): hashworks <mail@hashworks.net>
+
+# parabola changes and rationale:
+# - Added armv7h and i686 support
+# - Fixed architecture
+
+pkgname=kiwix-lib
+pkgver=5.1.0
+pkgrel=1
+pkgdesc="Library providing the Kiwix software core"
+license=('GPL3')
+arch=('armv7h' 'i686' 'x86_64')
+depends=('libzim>=5.0.0' 'pugixml' 'mustache' 'xapian-core' 'aria2')
+makedepends=('meson')
+url='https://github.com/kiwix/kiwix-lib'
+source=("https://github.com/kiwix/kiwix-lib/archive/${pkgver}.tar.gz")
+sha256sums=(573e1176e351fedc8b49c7746aef10746bf13c9f5a1df18186e0e6589215c546)
+
+build() {
+	cd "${pkgname}-${pkgver}"
+	# We want to ignore xapian ABI version mismatches
+	arch-meson build -Dwerror=false
+	ninja -C build
+}
+
+check() {
+	cd "${pkgname}-${pkgver}/build"
+	ninja meson-test
+}
+
+package() {
+	cd "${pkgname}-${pkgver}/build"
+	DESTDIR="${pkgdir}" ninja install
+}