1 files changed, 51 insertions, 0 deletions
diff --git a/pcr/initng-git/PKGBUILD b/pcr/initng-git/PKGBUILD
new file mode 100644
index 000000000..38279ad89
--- /dev/null
+++ b/pcr/initng-git/PKGBUILD
@@ -0,0 +1,51 @@
+# Maintainer: Luke Shumaker <lukeshu@sbcglobal.net>
+# Maintainer (AUR): Jens Staal <staal1978@gmail.com>
+
+_pkgname=initng
+pkgname=initng-git
+pkgver=20120517.1043
+pkgdesc="A full replacement for the old System V Init system"
+url="http://initng.org/"
+license=('GPL3')
+
+pkgrel=1
+arch=('i686' 'x86_64')
+provides=('init')
+depends=('dbus')
+makedepends=('git' 'acr' 'ftjam' 'makepkg-git')
+optdepends=('ncurses')
+options=(!strip)
+source=('git://github.com/initng/initng.git' fixes.patch)
+backup=(etc/initng/killall5-ignore)
+
+pkgver() {
+  cd "$srcdir/$_pkgname"
+  date -u +%Y%m%d.%H%M -d "$(git log -n1 --date=iso --format=format:'%cd')"
+}
+
+build() {
+  cd "$srcdir/$_pkgname"
+  patch -Np1 -i "$srcdir/fixes.patch"
+  acr
+  ./configure --prefix="/usr" --sbindir=/sbin --sysconfdir=/etc
+  jam
+}
+
+package() {
+  cd "$srcdir/$_pkgname"
+
+  jam install DESTDIR="$pkgdir"
+  find "$pkgdir"/usr/lib -type f -name '*.so*' -exec chmod 755 {} +
+  find "$pkgdir"/sbin    -type f               -exec chmod 755 {} +
+  pushd "$pkgdir"/usr/lib
+  ln -s libngeclient.so.* libngeclient.so.0
+  ln -s libngcclient.so.* libngcclient.so.0
+  popd
+
+  install -d "$pkgdir"/usr/share/licenses/initng
+  install -m644 COPYING "$pkgdir"/usr/share/licenses/initng/
+  install -m644 AUTHORS "$pkgdir"/usr/share/licenses/initng/
+}
+
+md5sums=('SKIP'
+         'bf6d17e00c5f0d85d99b7184980528ad')