1 files changed, 76 insertions, 0 deletions
diff --git a/pcr/dbus-elogind/PKGBUILD b/pcr/dbus-elogind/PKGBUILD
new file mode 100644
index 000000000..d6095e7b4
--- /dev/null
+++ b/pcr/dbus-elogind/PKGBUILD
@@ -0,0 +1,76 @@
+# Maintainer (Manjaro): artoo <artoo@manjaro.org>
+# Contributor (Manjaro): Jan de Groot <jgc@archlinux.org>
+# Contributor (Manjaro): Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
+# Contributor (Manjaro): Tom Gundersen <teg@jklm.no>
+# Contributor (Manjaro): Link Dupont <link@subpop.net>
+# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
+
+_pkgname=dbus
+_commit=8b582cb10d7cf00af7a70496aec48af24edc542b  # tags/dbus-1.10.16^0
+
+pkgname=dbus-elogind
+pkgver=1.10.16
+pkgrel=2
+pkgdesc="Freedesktop.org message bus system"
+url="https://wiki.freedesktop.org/www/Software/dbus/"
+arch=(i686 x86_64 armv7h)
+license=(GPL custom)
+provides=('libdbus' "dbus=$pkgver")
+conflicts=('libdbus' 'dbus' 'dbus-x11')
+depends=('expat' 'libx11' 'libelogind' 'libeudev')
+makedepends=('xmlto' 'docbook-xsl' 'python' 'yelp-tools' 'doxygen' 'git')
+optdepends=('dbus-openrc: dbus initscript')
+source=("git+https://anongit.freedesktop.org/git/dbus/dbus#commit=$_commit"
+        'dbus-enable-elogind.patch')
+sha256sums=('SKIP'
+            'faffcaa5b295f49fcedeed2c9ece5298949096be3062fd99a4bf1a6ac3ad1ea0')
+validpgpkeys=('DA98F25C0871C49A59EAFF2C4DE8FF2A63C7CC90'  # Simon McVittie <simon.mcvittie@collabora.co.uk>
+              '3C8672A0F49637FE064AC30F52A43A1E4B77B059') # Simon McVittie <simon.mcvittie@collabora.co.uk>
+
+prepare() {
+    cd $_pkgname
+    git cherry-pick -n 09cb6d7b467f6d1c6685ee9ccc171f4dddbe1f42
+    patch -Np 1 -i ${srcdir}/dbus-enable-elogind.patch
+    NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+    cd $_pkgname
+    ./configure \
+        --prefix=/usr \
+        --sysconfdir=/etc \
+        --localstatedir=/var \
+        --libexecdir=/usr/lib/dbus-1.0 \
+        --with-dbus-user=dbus \
+        --with-system-pid-file=/run/dbus/pid \
+        --with-system-socket=/run/dbus/system_bus_socket \
+        --with-console-auth-dir=/run/console/ \
+        --enable-inotify \
+        --disable-static \
+        --disable-verbose-mode \
+        --disable-asserts \
+        --with-systemdsystemunitdir=/usr/lib/systemd/system \
+        --disable-systemd \
+        --disable-user-session \
+        --enable-x11-autolaunch \
+        --enable-elogind
+    make
+}
+
+check() {
+    cd $_pkgname
+    make check
+}
+
+package() {
+    cd $_pkgname
+
+    make DESTDIR="$pkgdir" install
+
+    rm -r "$pkgdir/var/run"
+
+    install -Dm644 COPYING "$pkgdir/usr/share/licenses/$_pkgname/COPYING"
+
+    # Remove docs
+    rm -r "$pkgdir/usr/share/doc"
+}