1 files changed, 47 insertions, 0 deletions
diff --git a/nonsystemd/pcsclite/PKGBUILD b/nonsystemd/pcsclite/PKGBUILD
new file mode 100644
index 000000000..fdcd99197
--- /dev/null
+++ b/nonsystemd/pcsclite/PKGBUILD
@@ -0,0 +1,47 @@
+# Maintainer: David P. <megver83@parabola.nu>
+# Maintainer (Arch): Alad Wenter <alad@archlinux.org>
+# Maintainer (Arch): Christian Hesse <mail@eworm.de>
+# Contributor (Arch): Giovanni Scafora <giovanni@archlinux.org>
+# Contributor (Arch): Daniel Plaza <daniel.plaza.espi@gmail.com>
+
+pkgname=pcsclite
+pkgver=1.9.0
+pkgrel=1
+pkgrel+=.nonsystemd1
+pkgdesc="PC/SC Architecture smartcard middleware library"
+arch=('x86_64')
+arch+=('i686' 'armv7h')
+url='https://pcsclite.apdu.fr/'
+license=('BSD')
+depends=('python' 'libeudev')
+makedepends=('pkg-config' 'udev' 'libudev.so')
+provides=('libpcsclite.so' 'libpcscspy.so')
+options=('!docs')
+validpgpkeys=('F5E11B9FFE911146F41D953D78A1B4DFE8F9C57E') # Ludovic Rousseau <rousseau@debian.org>
+source=("https://pcsclite.apdu.fr/files/pcsc-lite-${pkgver}.tar.bz2"{,.asc})
+sha256sums=('0148d403137124552c5d0f10f8cdab2cbb8dfc7c6ce75e018faf667be34f2ef9'
+            'SKIP')
+
+build() {
+  cd "pcsc-lite-$pkgver"
+
+  ./configure \
+    --prefix=/usr \
+    --sbindir=/usr/bin \
+    --sysconfdir=/etc \
+    --enable-filter \
+    --enable-ipcdir=/run/pcscd \
+    --enable-libudev \
+    --enable-usbdropdir=/usr/lib/pcsc/drivers \
+    --disable-libsystemd
+
+  make
+}
+
+package() {
+  cd "pcsc-lite-$pkgver"
+  make DESTDIR="$pkgdir" install
+
+  install -D -m0644 "$srcdir/pcsc-lite-$pkgver/COPYING" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+  install -d "$pkgdir/usr/lib/pcsc/drivers"
+}