1 files changed, 45 insertions, 0 deletions
diff --git a/nonprism/gnome-settings-daemon/PKGBUILD b/nonprism/gnome-settings-daemon/PKGBUILD
new file mode 100644
index 000000000..dabbdf0fb
--- /dev/null
+++ b/nonprism/gnome-settings-daemon/PKGBUILD
@@ -0,0 +1,45 @@
+# $Id: PKGBUILD 264838 2016-04-13 20:22:06Z heftig $
+# Maintainer (Arch): Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
+# Maintainer: André Silva <emulatorman@parabola.nu>
+
+pkgname=gnome-settings-daemon
+pkgver=3.20.1
+pkgrel=1.nonprism1
+pkgdesc="The GNOME Settings daemon, without geoclue2 support"
+arch=(i686 x86_64)
+license=(GPL)
+depends=(dconf gnome-desktop gsettings-desktop-schemas libcanberra-pulse
+         libnotify libsystemd libwacom pulseaudio pulseaudio-alsa upower librsvg libgweather
+         geocode-glib nss libgudev libnm-glib)
+makedepends=(intltool xf86-input-wacom libxslt docbook-xsl python2)
+options=('!emptydirs')
+install=gnome-settings-daemon.install
+url="http://www.gnome.org"
+groups=(gnome)
+source=(https://download.gnome.org/sources/$pkgname/${pkgver:0:4}/$pkgname-$pkgver.tar.xz
+        nonprism.patch)
+sha256sums=('e84a075d895ca3baeefb8508e0a901027b66f7d5a7ee8c966e31d301b38e78e7'
+            '27fba52c36ee9d072e9602e843af55d970f128eb7ede1a828e86ea874765b1a6')
+
+prepare() {
+  cd $pkgname-$pkgver
+
+  patch -p1 -i $srcdir/nonprism.patch
+}
+
+build() {
+  cd $pkgname-$pkgver
+
+  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
+      --libexecdir=/usr/lib/$pkgname --disable-static
+
+  #https://bugzilla.gnome.org/show_bug.cgi?id=656231
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+
+  make
+}
+
+package() {
+  cd $pkgname-$pkgver
+  make DESTDIR="$pkgdir" install
+}