1 files changed, 51 insertions, 0 deletions
diff --git a/libre/kdevelop/PKGBUILD b/libre/kdevelop/PKGBUILD
new file mode 100644
index 000000000..29d9cc1a1
--- /dev/null
+++ b/libre/kdevelop/PKGBUILD
@@ -0,0 +1,51 @@
+# $Id$
+# Maintainer (Arch): Antonio Rojas <arojas@archlinux.org>
+# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>
+# Contributor (Arch): Giovanni Scafora <giovanni@archlinux.org>
+
+pkgname=kdevelop
+pkgver=5.2.1
+pkgrel=1.parabola1
+pkgdesc='C++ IDE using KDE technologies, without qt5-webengine dependency'
+arch=(x86_64 i686 armv7h)
+url='http://www.kdevelop.org/'
+license=(GPL)
+depends=(clang libksysguard kitemmodels knotifyconfig ktexteditor grantlee libkomparediff2 qt5-webkit
+         kcmutils threadweaver knewstuff)
+makedepends=(extra-cmake-modules kdoctools kdevelop-pg-qt llvm qt5-tools plasma-framework krunner okteta python mesa
+             boost purpose subversion)
+optdepends=('konsole: embedded terminal'
+            'git: Git support' 'subversion: SVN support' 'cvs: CVS support'
+            'gdb: GNU debugger support' 'lldb: LLDB debugger support'
+            'qt5-doc: Qt documentation integration'
+            'cmake: cmake integration'
+            'qt5-tools: qthelp plugin'
+            'okteta: GNU debugger support'
+            'plasma-framework: for the plasma addons'
+            'purpose: patch review plugin'
+            'cppcheck: code analyzer' 'heaptrack: memory profiler')
+conflicts=(kdevelop-qmljs kdevplatform)
+replaces=(kdevelop-qmljs kdevplatform)
+source=("https://download.kde.org/stable/$pkgname/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.asc})
+sha256sums=('d1c39c563e4fada89eb9f30bd43c6c4beed0fec7ca7d124af587193cfe020650'
+            'SKIP')
+validpgpkeys=('329FD02C5AA48FCC77A4BBF0AC44AC6DB29779E6') # Sven Brauch <mail@svenbrauch.de>
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build
+  cmake ../$pkgname-$pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DBUILD_TESTING=OFF
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+}