1 files changed, 46 insertions, 0 deletions
diff --git a/libre/virt-manager-i686/PKGBUILD b/libre/virt-manager-i686/PKGBUILD
new file mode 100644
index 000000000..c8690799c
--- /dev/null
+++ b/libre/virt-manager-i686/PKGBUILD
@@ -0,0 +1,46 @@
+# Maintainer (Arch): Sergej Pupykin <pupykin.s+arch@gmail.com>
+# Contributor (Arch): Daniel Micay <danielmicay@gmail.com>
+# Contributor (Arch): Jonathan Wiersma <archaur at jonw dot org>
+# Maintainer (Hyperbola): André Silva <emulatorman@hyperbola.info>
+# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
+
+pkgbase=virt-manager
+pkgname=(virt-install)
+pkgver=2.0.0
+pkgrel=3
+pkgrel+=.par1
+pkgdesc="Console user interface for managing virtual machines, without non-FSDG compliant distros and operating systems support"
+arch=('i686')
+url="http://virt-manager.org/"
+license=('GPL')
+depends=('libosinfo' 'libvirt-python' 'python-gobject' 'python-requests')
+makedepends=('intltool')
+source=("https://virt-manager.org/download/sources/virt-manager/virt-manager-$pkgver.tar.gz"
+        'libre.patch')
+sha512sums=('5d0eb65dceb5c913973edaa52414b1665d1ed9cd3f226e28a592decddec2acd8fdb589f60736edf9b7d95830893812f9aecca2cbdd715033ca7ea53a95472876'
+            'de6b88810094bf55515e32bfb6ff5abeb06a8f79c74095e8d57bf48423033eb3835bc9c21433e8525f362c2b144f9819437e46e7aabf64c54e7b3bfb7285e706')
+
+prepare() {
+  cd "$srcdir/$pkgbase-$pkgver"
+  patch -p1 -i ../libre.patch
+}
+
+build() {
+  cd "$srcdir/$pkgbase-$pkgver"
+  python setup.py build
+}
+
+package_virt-install() {
+  cd "$srcdir/$pkgbase-$pkgver"
+  python setup.py --no-update-icon-cache --no-compile-schemas install --root "$pkgdir"
+  python -m compileall "${pkgdir}/usr/share/virt-manager"
+  python -O -m compileall "${pkgdir}/usr/share/virt-manager"
+
+  # Split virt-manager
+  [[ -d $srcdir/virt-manager ]] && rm -r "$srcdir/virt-manager/"
+  mkdir "$srcdir"/virt-manager
+  mv "$pkgdir"/usr/bin/virt-manager \
+     "$pkgdir"/usr/share/{appdata,applications,glib-2.0,icons}/ \
+     "$pkgdir"/usr/share/man/man1/virt-manager.1 \
+     "$srcdir/virt-manager/"
+}