1 files changed, 60 insertions, 0 deletions
diff --git a/libre/rz-cutter/PKGBUILD b/libre/rz-cutter/PKGBUILD
new file mode 100644
index 000000000..a15377d63
--- /dev/null
+++ b/libre/rz-cutter/PKGBUILD
@@ -0,0 +1,60 @@
+# Maintainer (arch): Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Maintainer (arch): Santiago Torres-Arias <santiago[at]archlinux[dot]org>
+# Contributor: Aaron McDaniel (mcd1992) <'aur' at the domain 'fgthou.se'>
+# Maintainer: bill-auger <bill-auger@programmer.net>
+
+pkgname=rz-cutter
+_gitcommit=6dab092b515024ba769e81554c91c0d8b9883264
+pkgver=2.0.3
+pkgrel=2
+pkgrel+=.parabola1
+pkgdesc='Qt and C++ GUI for rizin reverse engineering framework'
+url='https://github.com/rizinorg/cutter'
+arch=('x86_64')
+arch+=('armv7h' 'i686')
+license=('GPL3')
+depends=('rizin' 'capstone' 'qt5-base' 'qt5-svg' 'qt5-webengine' 'icu' 'python' 'jupyter'
+         'pyside2' 'python-shiboken2' 'graphviz' 'gcc-libs' 'syntax-highlighting')
+depends=( ${depends[@]/qt5-webengine/} )
+makedepends=('git' 'cmake' 'ninja' 'shiboken2' 'qt5-tools')
+optdepends=('rz-ghidra: ghidra decompiler plugin')
+source=("git+https://github.com/rizinorg/cutter#commit=${_gitcommit}"
+        "git+https://github.com/rizinorg/cutter-translations")
+sha512sums=('SKIP'
+            'SKIP')
+b2sums=('SKIP'
+        'SKIP')
+
+pkgver() {
+  cd cutter
+  git describe --tags --match 'v*' | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+prepare() {
+  cd cutter
+  git config 'submodule.src/translations.url' "${srcdir}/cutter-translations"
+  git submodule update --init src/translations
+}
+
+build() {
+  cd cutter
+  cmake -B build \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_BUILD_TYPE=None \
+    -DCUTTER_ENABLE_PYTHON=ON \
+    -DCUTTER_ENABLE_PYTHON_BINDINGS=ON \
+    -DCUTTER_USE_BUNDLED_RIZIN=OFF \
+    -DCUTTER_USE_ADDITIONAL_RIZIN_PATHS=OFF \
+    -DCUTTER_ENABLE_CRASH_REPORTS=OFF \
+    -DCUTTER_ENABLE_GRAPHVIZ=ON \
+    -Wno-dev \
+    -G Ninja
+  ninja -C build
+}
+
+package() {
+  cd cutter
+  DESTDIR="${pkgdir}" ninja -C build install
+  install -d "${pkgdir}/usr/share/doc/${pkgname}"
+  cp -a docs/* "${pkgdir}/usr/share/doc/${pkgname}"
+}