1 files changed, 66 insertions, 0 deletions
diff --git a/libre/java-hamcrest/PKGBUILD b/libre/java-hamcrest/PKGBUILD
new file mode 100644
index 000000000..0ae7f0c95
--- /dev/null
+++ b/libre/java-hamcrest/PKGBUILD
@@ -0,0 +1,66 @@
+# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
+
+_libname=hamcrest
+pkgname=java-${_libname}
+pkgver=1.3
+pkgrel=3.parabola1
+pkgdesc="Java matcher objects library"
+arch=('any')
+url="https://code.google.com/p/hamcrest"
+license=('BSD')
+depends=('java-runtime')
+makedepends=('apache-ant' 'easymock' 'java-jarjar' 'java-qdox' 'jmock' 'jh' 'junit')
+source=("https://${_libname}.googlecode.com/files/${_libname}-${pkgver}.tgz"
+        "hamcrest-build.patch"
+        "hamcrest-random_compilation_failure.patch")
+md5sums=('92e91c2754d44e49b72d70c10a04cb08'
+         '37e8a9c44743d52054d690e98bee013a'
+         'b0009aa6a6a6ea97987016d9d323c949')
+
+prepare() {
+  cd "${srcdir}/${_libname}-${pkgver}"
+  rm -v $(find . -name \*.jar)
+  patch -Np1 -i "${srcdir}/hamcrest-build.patch"
+  patch -Np1 -i "${srcdir}/hamcrest-random_compilation_failure.patch"
+}
+
+build() {
+  cd "${srcdir}/${_libname}-${pkgver}"
+  ant bigjar unit-test javadoc \
+    -Dhaltonfailure=false -Dversion=${pkgver}
+}
+
+package() {
+  cd "${srcdir}/${_libname}-${pkgver}"
+
+  # Install license file
+  install -Dm644 LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.txt"
+
+  # Install documentation
+  install -d "${pkgdir}/usr/share/doc/${pkgname}"
+  cp -r "build/temp/hamcrest-all-${pkgver}-javadoc.jar.contents" \
+    "${pkgdir}/usr/share/doc/${pkgname}/javadoc"
+
+  # Install Maven artifacts
+  install -d "${pkgdir}/usr/share/java/${_libname}"
+  export DESTDIR=${pkgdir}
+  for artifact in $(printf '%s\n' *.pom|sed 's/-[0-9.]*\.pom$//'); do
+    if [[ -f "build/${artifact}-${pkgver}.jar" ]]; then
+      # This artifact has a jar file
+      jh mvn-install "org.hamcrest" ${artifact} ${pkgver} \
+        "${artifact}-${pkgver}.pom" \
+        "build/${artifact}-${pkgver}.jar" \
+        "${artifact}.jar"
+
+      # Symlink them to /usr/share/java
+      ln -s "/usr/share/java/${artifact}.jar" \
+        "${pkgdir}/usr/share/java/${artifact//-/\/}-${pkgver}.jar"
+      ln -s "/usr/share/java/${artifact}.jar" \
+        "${pkgdir}/usr/share/java/${artifact//-/\/}.jar"
+    else
+      # This artifact is just a pom
+      jh mvn-install "org.hamcrest" ${artifact} ${pkgver} \
+        "${artifact}-${pkgver}.pom"
+    fi
+  done
+}