1 files changed, 103 insertions, 0 deletions
diff --git a/libre/aarch64-linux-gnu-gcc-initial/PKGBUILD b/libre/aarch64-linux-gnu-gcc-initial/PKGBUILD
new file mode 100644
index 000000000..f78753f2a
--- /dev/null
+++ b/libre/aarch64-linux-gnu-gcc-initial/PKGBUILD
@@ -0,0 +1,103 @@
+# Maintainer: Denis 'GNUtoo' Carikli <GNUtoo@no-log.org>
+# Feel free to push modifications or take over maintainership
+
+_target=aarch64-linux-gnu
+pkgname=$_target-gcc-initial
+_pkgver=9.3.0
+pkgver=$_pkgver
+_islver=0.22
+pkgrel=1
+pkgrel+=parabola1
+pkgdesc='The GNU Compiler Collection - cross compiler for aarch64 target'
+arch=(x86_64 i686 armv7h)
+url='http://gcc.gnu.org/'
+license=(GPL LGPL FDL)
+depends=($_target-binutils libmpc zlib)
+makedepends=(gmp mpfr)
+provides+=("${_target}-gcc")
+conflicts+=("${_target}-gcc")
+replaces+=("${_target}-gcc")
+options=(!emptydirs !strip)
+source=(https://gcc.gnu.org/pub/gcc/releases/gcc-$_pkgver/gcc-$_pkgver.tar.xz{,.sig}
+        http://isl.gforge.inria.fr/isl-$_islver.tar.bz2)
+sha512sums=('4b9e3639eef6e623747a22c37a904b4750c93b6da77cf3958d5047e9b5ebddb7eebe091cc16ca0a227c0ecbd2bf3b984b221130f269a97ee4cc18f9cf6c444de'
+            'SKIP'
+            'fc2c9796979610dd51143dcefe4f5c989c4354571cc5a1fcc6b932fd41f42a54f6b43adfd289af61be7bd06f3a523fa6a7d7ee56680e32d8036beb4c188fa668')
+validpgpkeys=(33C235A34C46AA3FFB293709A328C3A2C3C45C06) # Jakub Jelinek <jakub@redhat.com>
+
+if [ -n "$_snapshot" ]; then
+  _basedir=gcc-$_snapshot
+else
+  _basedir=gcc-$_pkgver
+fi
+
+prepare() {
+  cd $_basedir
+
+  # link isl for in-tree builds
+  ln -sf ../isl-$_islver isl
+
+  echo $_pkgver > gcc/BASE-VER
+
+  # hack! - some configure tests for header files using "$CPP $CPPFLAGS"
+  sed -i "/ac_cpp=/s/\$CPPFLAGS/\$CPPFLAGS -O2/" "$srcdir"/$_basedir/{libiberty,gcc}/configure
+
+  mkdir $srcdir/gcc-build
+}
+
+build() {
+  cd gcc-build
+
+  # using -pipe causes spurious test-suite failures
+  # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=48565
+  CFLAGS=${CFLAGS/-pipe/}
+  CXXFLAGS=${CXXFLAGS/-pipe/}
+
+  $srcdir/$_basedir/configure \
+    --target=$_target \
+    --prefix=/usr \
+    --libexecdir=/usr/lib \
+    --enable-languages=c,c++ \
+    --enable-plugins \
+    --enable-shared \
+    --disable-decimal-float \
+    --disable-libffi \
+    --disable-libgomp \
+    --disable-libmudflap \
+    --disable-libquadmath \
+    --disable-libssp \
+    --disable-libstdcxx-pch \
+    --disable-nls \
+    --disable-threads \
+    --disable-tls \
+    --disable-multilib \
+    --with-gnu-as \
+    --with-gnu-ld \
+    --with-system-zlib \
+    --with-gmp \
+    --with-mpfr \
+    --with-mpc \
+    --with-isl \
+    --with-libelf \
+    --enable-gnu-indirect-function
+
+  make all-gcc
+}
+
+package() {
+  make -C gcc-build DESTDIR="$pkgdir" install-gcc
+
+  # strip target binaries
+  find "$pkgdir"/usr/lib/gcc/$_target/ \
+       -type f -and \( -name \*.a -or -name \*.o \) \
+       -exec $_target-objcopy -R .comment -R .note -R .debug_info -R .debug_aranges \
+           -R .debug_pubnames -R .debug_pubtypes -R .debug_abbrev -R .debug_line \
+           -R .debug_str -R .debug_ranges -R .debug_loc '{}' \;
+
+  # strip host binaries
+  find "$pkgdir/usr/bin/" "$pkgdir/usr/lib/gcc/$_target/" -type f \
+    -and \( -executable \) -exec strip '{}' \;
+
+  # Remove files that conflict with host gcc package
+  rm -r "$pkgdir/usr/share/"{man/man7,info}
+}