1 files changed, 48 insertions, 0 deletions
diff --git a/libre-testing/konqueror/PKGBUILD b/libre-testing/konqueror/PKGBUILD
new file mode 100644
index 000000000..79dd7519f
--- /dev/null
+++ b/libre-testing/konqueror/PKGBUILD
@@ -0,0 +1,48 @@
+# Maintainer (Arch): Antonio Rojas <arojas@archlinux,org>
+# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
+# Maintainer: André Silva <emulatorman@parabola.nu>
+# Contributor: Michał Masłowski <mtjm@mtjm.eu>
+
+pkgname=konqueror
+pkgver=16.12.2
+pkgrel=1.parabola2
+pkgdesc="KDE File Manager & Web Browser, without Google, nonfree software recommendation and nonfree qt5-webengine support"
+arch=(i686 x86_64 armv7h)
+url="https://konqueror.org/"
+license=(LGPL)
+depends=(dolphin keditbookmarks)
+makedepends=(extra-cmake-modules kdoctools python tidy kdesignerplugin kdesu)
+optdepends=('tidy: tidy HTML plugin' 'kdesu: shell command plugin')
+conflicts=(kdebase-konqueror kdebase-konq-plugins)
+replaces=(kdebase-konqueror kdebase-konq-plugins)
+groups=(kde-applications kdebase)
+source=("http://download.kde.org/stable/applications/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig}
+        'libre.patch')
+md5sums=('ebc2f5db4aa377ca11d4e4a7cdf3bf7f'
+         'SKIP'
+         'dc679b64429e08e541f27268a8faadd6')
+validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7) # Albert Astals Cid <aacid@kde.org>
+
+prepare() {
+  mkdir -p build
+
+  cd $pkgname-$pkgver
+  # Remove nonfree WebEngine support and nonfree software or Google recommendation
+  rm -rv webenginepart
+  patch -p1 -i ../libre.patch
+}
+
+build() {
+  cd build
+  cmake ../$pkgname-$pkgver \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DBUILD_TESTING=OFF
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+}