1 files changed, 61 insertions, 0 deletions
diff --git a/pcr/gegl-devel/PKGBUILD b/pcr/gegl-devel/PKGBUILD
new file mode 100644
index 000000000..14947d467
--- /dev/null
+++ b/pcr/gegl-devel/PKGBUILD
@@ -0,0 +1,61 @@
+# Maintainer: Márcio Silva <coadde@parabola.nu>
+# based of gegl
+
+_pkgname=gegl
+pkgname=gegl-devel
+pkgver=0.3.6
+pkgrel=1
+pkgdesc="Graph based image processing framework, with babl-devel 0.1.16"
+arch=('i686' 'x86_64' 'armv7h')
+url="http://www.gegl.org/"
+license=('GPL3' 'LGPL3')
+depends=('babl-devel' 'libspiro' 'json-glib')
+makedepends=('intltool' 'ruby' 'lua' 'libraw' 'openexr' 'mesa' 'glu' 'ffmpeg' 'librsvg'
+             'jasper' 'libtiff' 'exiv2' 'vala' 'python2' 'suitesparse' 'lensfun'
+             'gobject-introspection' 'git')
+optdepends=('libraw: raw plugin'
+            'openexr: openexr plugin'
+            'ffmpeg: ffmpeg plugin'
+            'suitesparse: matting-levin plugin'
+            'librsvg: svg plugin'
+            'jasper: jasper plugin'
+            'libtiff: tiff plugin'
+            'lua: lua plugin'
+            'lensfun: lens-correct plugin')
+provides=("$_pkgname")
+conflicts=("$_pkgname")
+source=("git://git.gnome.org/gegl#tag=GEGL_${pkgver//./_}")
+sha256sums=('SKIP')
+
+prepare() {
+  mkdir path
+  ln -s /usr/bin/python2 path/python
+
+  cd ${_pkgname}
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  export PATH="$srcdir/path:$PATH" PYTHON=/usr/bin/python2
+  cd ${_pkgname}
+  ./configure  --prefix=/usr  --with-sdl --with-librsvg \
+    --with-libavformat --with-jasper --disable-docs \
+    --enable-workshop
+
+  # https://bugzilla.gnome.org/show_bug.cgi?id=655517
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+
+  make
+}
+
+check() {
+  export PATH="$srcdir/path:$PATH" PYTHON=/usr/bin/python2
+  cd ${_pkgname}
+  make -k check || :
+}
+
+package() {
+  export PATH="$srcdir/path:$PATH" PYTHON=/usr/bin/python2
+  cd ${_pkgname}
+  make DESTDIR="${pkgdir}" install
+}