mv ~lukeshu/holo{-lukeshu,}

1 files changed, 62 insertions, 0 deletions

diff --git a/~lukeshu/holo/PKGBUILD b/~lukeshu/holo/PKGBUILD
new file mode 100644
index 000000000..13800e354
--- /dev/null
+++ b/~lukeshu/holo/PKGBUILD
@@ -0,0 +1,62 @@
+# Maintainer (AUR): Stefan Majewsky <majewsky@gmx.net>
+# Maintainer: Luke Shumaker <lukeshu@parabola.nu>
+
+pkgname='holo'
+pkgver=2.2
+pkgrel=3
+pkgdesc='Minimalistic configuration management'
+arch=('i686' 'x86_64' 'armv7h')
+url='http://holocm.org'
+license=('GPL3')
+depends=()
+optdepends=(
+    'git: to display diffs of entities'
+    'openssh: for the holo-ssh-keys plugin'
+    'shadow: for the holo-users-groups plugin'
+)
+makedepends=('go' 'perl')
+checkdepends=('git' 'openssh')
+provides=(
+    # required for holo-build packages that have a holo-$PLUGIN dependency when there are files below /usr/share/holo/$PLUGIN/
+    "holo-files=${pkgver}"
+    "holo-run-scripts=${pkgver}"
+    "holo-ssh-keys=${pkgver}"
+    "holo-users-groups=${pkgver}"
+)
+conflicts=("${provides[@]%=*}")
+replaces=("${provides[@]%=*}")
+backup=(
+    'etc/holorc'
+    'etc/holorc.d/10-files'
+    'etc/holorc.d/20-users-groups'
+    'etc/holorc.d/25-ssh-keys'
+    'etc/holorc.d/95-holo-run-scripts'
+)
+
+# patch info
+pkgver+=.lukeshu1
+pkgrel+=.1
+pkgdesc+=" (with patches from lukeshu)"
+_gitver='commit=ec2b9a5a3d2d3384a84ed45dbc38eb689003e835'
+mksource=("$pkgname-$pkgver::git+https://github.com/lukeshu/holo#$_gitver")
+mkmd5sums=('SKIP')
+replaces+=('holo-lukeshu')
+source=("https://repo.parabola.nu/other/~lukeshu/holo/$pkgname-$pkgver.tar.gz")
+sha256sums=('ad64d5af1b08a6ec0053fe9a729052152d3f77c8488f791cc99cee5c12faf72d')
+
+options=('!strip') # binaries are already stripped inside the Makefile
+
+build() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+    make
+}
+
+check() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+    make check
+}
+
+package() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+    make install DESTDIR="${pkgdir}"
+}