~fauno/notmuch-6.0

1 files changed, 53 insertions, 0 deletions

diff --git a/~fauno/notmuch/PKGBUILD b/~fauno/notmuch/PKGBUILD
new file mode 100644
index 000000000..e7425dabf
--- /dev/null
+++ b/~fauno/notmuch/PKGBUILD
@@ -0,0 +1,53 @@
+# Maintainer: fauno <fauno at kiwwwi.com.ar>
+# Maintainer: Olivier Ramonat <olivier at ramonat dot fr>
+# Maintainer: Richard Murri <admin@richardmurri.com>
+
+pkgname=notmuch
+pkgver=0.6
+pkgrel=1
+pkgdesc="Notmuch is not much of an email program"
+arch=(i686 x86_64)
+url="http://notmuchmail.org/"
+license=('GPL3')
+depends=('xapian-core' 'gmime')
+makedepends=('talloc' 'python2' 'emacs-nox' 'gnupg')
+optdepends=('emacs: for using the emacs interface'
+            'vim: for using the vim interface'
+            'python2: for using the python bindings'
+            'gnupg: for email encryption')
+source=("http://notmuchmail.org/releases/${pkgname}-${pkgver}.tar.gz")
+
+build() {
+  cd "$srcdir/${pkgname}-${pkgver}"
+
+  ./configure --prefix=/usr --sysconfdir=/etc
+  make 
+}
+
+check() {
+  cd "$srcdir/${pkgname}-${pkgver}"
+  make test
+}
+
+package(){
+  cd "$srcdir/${pkgname}-${pkgver}"
+  make DESTDIR="$pkgdir/" LIBDIR_IN_LDCONFIG=0 install
+
+  install -D notmuch $pkgdir/usr/sbin/notmuch
+
+  mkdir -p $pkgdir/usr/share/vim/vimfiles/{plugin,syntax}
+
+  cd vim && make PREFIX="$pkgdir/usr/share/vim/vimfiles" install
+
+  # Install python bindings
+
+  cd "$srcdir/${pkgname}-${pkgver}/bindings/python"
+
+  find "." -name '*.py' -print0 |xargs -0 \
+      sed -i -e 's,^#!/usr/bin/env python$,#!/usr/bin/env python2,' \
+      -e 's,^#!/usr/bin/python$,#!/usr/bin/python2,'
+  ln -s ../../lib/libnotmuch.so.1 libnotmuch.so.1
+  env LD_LIBRARY_PATH="." python2 setup.py build
+  env LD_LIBRARY_PATH="." python2 setup.py install --prefix=/usr --root=$pkgdir
+}
+md5sums=('be8ce01bb6f84ca66bfc9a76c63276ac')