spyder Scientific PYthon Development EnviRonment providing MATLAB-like

3 files changed, 91 insertions, 0 deletions

diff --git a/pcr/spyder/PKGBUILD b/pcr/spyder/PKGBUILD
new file mode 100644
index 000000000..1e9c456a1
--- /dev/null
+++ b/pcr/spyder/PKGBUILD
@@ -0,0 +1,51 @@
+# Contributor (Arch)     : Muflone http://url.muflone.com/contacts
+# Contributor (Arch)     : Francois Boulogne <fboulogne@april.org>
+# Contributor (Arch)     : TDY <tdy@gmx.com>
+# Maintainer  (Parabola) : Aurélien DESBRIÈRES <aurelien@hackers.camp>
+
+pkgname=spyder
+pkgver=2.2.5
+pkgrel=2
+pkgdesc='Scientific PYthon Development EnviRonment providing MATLAB-like features.'
+arch=('any')
+url='http://code.google.com/p/spyderlib/'
+license=('MIT')
+install="${pkgname}.install"
+depends=('python2-pyqt4' 'python2-pyflakes' 'desktop-file-utils' 'gtk-update-icon-cache' 'python2-pyzmq' 'python2-pygments')
+makedepends=('python2-sphinx' 'python2-setuptools')
+optdepends=('python2-pylint: powerful code analysis'
+            'ipython2: enhanced Python interpreter'
+            'python2-rope: editor code completion, calltips and go-to-definition'
+            'python2-sphinx: rich text help on the object inspector'
+            'python2-numpy: N-dimensional arrays'
+            'python2-scipy: signal/image processing'
+            'python2-psutil: memory/CPU usage in the status bar'
+            'python2-h5py: HDF5 support'
+            'python2-matplotlib: interactive 2D/3D data plotting'
+            'pep8-python2: real-time code style analysis'
+            'python2-sympy: symbolic mathematics for the IPython console')
+source=("http://spyderlib.googlecode.com/files/${pkgname}-${pkgver}.zip" 
+        "pylint.patch")
+md5sums=('1c9aa650dae9f883616e917803f8a3be'
+         '3fe95915036634841b619670ad947e96')
+
+prepare() {
+  patch -p0 < "pylint.patch"
+}
+
+build() {
+  cd "${pkgname}-${pkgver}"
+  python2 setup.py build
+}
+
+package() {
+  cd "${pkgname}-${pkgver}"
+  python2 setup.py install --prefix=/usr --root="${pkgdir}" --optimize=1
+  # Install license file
+  install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+  # Install icon and desktop file
+  install -D -m644 "scripts/${pkgname}.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
+  install -D -m644 "spyderlib/images/spyder.svg" "${pkgdir}/usr/share/icons/hicolor/scalable/apps/${pkgname}.svg"
+  # Remove useless spyder_win_post_install script
+  rm -f "${pkgdir}/usr/bin/spyder_win_post_install.py"
+}
diff --git a/pcr/spyder/pylint.patch b/pcr/spyder/pylint.patch
new file mode 100644
index 000000000..faa1edcf1
--- /dev/null
+++ b/pcr/spyder/pylint.patch
@@ -0,0 +1,28 @@
+diff -Naur spyder-2.2.5/spyderplugins/widgets/pylintgui.py spyder-2.2.5-patched/spyderplugins/widgets/pylintgui.py
+--- spyder-2.2.5/spyderplugins/widgets/pylintgui.py	2013-10-12 20:35:52.000000000 +0200
++++ spyder-2.2.5-patched/spyderplugins/widgets/pylintgui.py	2013-11-12 00:42:22.809509805 +0100
+@@ -40,7 +40,7 @@
+ _ = get_translation("p_pylint", dirname="spyderplugins")

+ 

+ 

+-PYLINT_PATH = programs.find_program('pylint')

++PYLINT_PATH = programs.find_program('pylint2')

+ 

+ 

+ def get_pylint_version():

+@@ -48,13 +48,13 @@
+     global PYLINT_PATH

+     if PYLINT_PATH is None:

+         return

+-    process = subprocess.Popen(['pylint', '--version'],

++    process = subprocess.Popen(['pylint2', '--version'],

+                                stdout=subprocess.PIPE, stderr=subprocess.PIPE,

+                                cwd=osp.dirname(PYLINT_PATH),

+                                shell=True if os.name == 'nt' else False)

+     lines = to_unicode_from_fs(process.stdout.read()).splitlines()

+     if lines:

+-        match = re.match('(pylint|pylint-script.py) ([0-9\.]*)', lines[0])

++        match = re.match('(pylint2|pylint-script.py) ([0-9\.]*)', lines[0])

+         if match is not None:

+             return match.groups()[1]

+ 

diff --git a/pcr/spyder/spyder.install b/pcr/spyder/spyder.install
new file mode 100644
index 000000000..62a045c59
--- /dev/null
+++ b/pcr/spyder/spyder.install
@@ -0,0 +1,12 @@
+post_install() {
+  update-desktop-database -q
+  gtk-update-icon-cache -q -f /usr/share/icons/hicolor
+}
+
+post_upgrade() {
+  post_install
+}
+
+post_remove() {
+  post_install
+}