java-geronimo-interceptor: add new package to [pcr]

1 files changed, 48 insertions, 0 deletions

diff --git a/pcr/java-geronimo-interceptor/PKGBUILD b/pcr/java-geronimo-interceptor/PKGBUILD
new file mode 100644
index 000000000..cd36c2cc2
--- /dev/null
+++ b/pcr/java-geronimo-interceptor/PKGBUILD
@@ -0,0 +1,48 @@
+# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
+
+_pkgname=geronimo-interceptor_3.0_spec
+pkgname=java-geronimo-interceptor
+pkgver=1.0.1
+pkgrel=1
+pkgdesc="Geronimo API implementation of the Interceptor 3.0 spec"
+arch=('any')
+url="http://geronimo.apache.org/"
+license=('APACHE')
+depends=('java-runtime')
+makedepends=('java-environment' 'jh' 'subversion')
+source=("${pkgname}-${pkgver}::svn+https://svn.apache.org/repos/asf/geronimo/specs/tags/${_pkgname}-${pkgver}/")
+md5sums=('SKIP')
+
+prepare() {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+  mkdir -p build/classes
+}
+
+build() {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+
+  javac -encoding "UTF-8" -d build/classes $(find "src/main/java" -name \*.java)
+  javadoc -encoding "UTF-8" -sourcepath "src/main/java" -d build/javadoc javax.interceptor
+
+  jar -cvf "${_pkgname}.jar" -C build/classes .
+}
+
+package() {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+
+  # Install license file
+  install -Dm644 LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.txt"
+
+  # Install documentation
+  install -d "${pkgdir}/usr/share/doc/${pkgname}"
+  cp -r "build/javadoc" "${pkgdir}/usr/share/doc/${pkgname}"
+
+  # Install Maven artifacts
+  export DESTDIR=${pkgdir}
+  jh mvn-install "org.apache.geronimo.specs" ${_pkgname} ${pkgver} \
+    "${srcdir}/${pkgname}-${pkgver}/pom.xml" \
+    "${srcdir}/${pkgname}-${pkgver}/${_pkgname}.jar" \
+    "${_pkgname}.jar"
+  ln -s "/usr/share/java/${_pkgname}.jar" \
+    "${pkgdir}/usr/share/java/${_pkgname}-${pkgver}.jar"
+}
\ No newline at end of file