belle-sip-git: add new package to [pcr]

1 files changed, 46 insertions, 0 deletions

diff --git a/pcr/belle-sip-git/PKGBUILD b/pcr/belle-sip-git/PKGBUILD
new file mode 100644
index 000000000..39e2cb24d
--- /dev/null
+++ b/pcr/belle-sip-git/PKGBUILD
@@ -0,0 +1,46 @@
+# Maintainer: André Silva <emulatorman@parabola.nu>
+
+_pkgname=belle-sip
+pkgname=belle-sip-git
+pkgver=r1540.2f08fe8
+pkgrel=1
+pkgdesc="A Voice-over-IP phone"
+arch=('i686' 'x86_64')
+url="https://github.com/BelledonneCommunications/belle-sip"
+license=('GPL2')
+depends=('libantlr3c' 'gcc-libs' 'mbedtls' 'bcunit-git' 'bctoolbox-git')
+makedepends=('java-runtime' 'git')
+conflicts=("${_pkgname}")
+provides=("${_pkgname}")
+options=('!emptydirs')
+source=("${_pkgname}-${pkgver}::git+https://github.com/BelledonneCommunications/belle-sip#branch=master"
+	"antlr.jar::https://github.com/antlr/website-antlr3/blob/gh-pages/download/antlr-3.4-complete.jar?raw=true")
+noextract=('antlr.jar')
+md5sums=('SKIP'
+         '1b91dea1c7d480b3223f7c8a9aa0e172')
+
+pkgver() {
+  cd $_pkgname-$pkgver
+  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+prepare() {
+  cd $_pkgname-$pkgver
+  ./autogen.sh
+  sed -i \
+    -e "s#antlr_java_prefixes=.*#antlr_java_prefixes=$srcdir#" \
+    -e "s|-Werror||g" \
+    configure{,.ac}
+}
+
+build() {
+  cd $_pkgname-$pkgver
+  ./configure --prefix=/usr  --libexecdir=/usr/lib/$_pkgname \
+    --disable-tests --disable-static --enable-tls
+  make
+}
+
+package() {
+  cd $_pkgname-$pkgver
+  make DESTDIR="$pkgdir" install
+}