sylpheed-nonprism: add new package for nonprism repo

1 files changed, 52 insertions, 0 deletions

diff --git a/nonprism/sylpheed-nonprism/PKGBUILD b/nonprism/sylpheed-nonprism/PKGBUILD
new file mode 100644
index 000000000..34d15ce73
--- /dev/null
+++ b/nonprism/sylpheed-nonprism/PKGBUILD
@@ -0,0 +1,52 @@
+# $Id: PKGBUILD 79630 2012-11-09 11:59:02Z speps $
+# Maintainer: speps <speps at aur dot archlinux dot org>
+# Contributor: Alexander Fehr <pizzapunk gmail com>
+# Contributor: dorphell <dorphell@archlinux.org>
+# Maintainer (Parabola): André Silva <emulatorman@parabola.nu>
+# Contributor (Parabola): Aditya Som <icarious@hacari.org>"
+
+_pkgname=sylpheed
+pkgname=sylpheed-nonprism
+pkgver=3.3.0
+pkgrel=1
+pkgdesc="Lightweight and user-friendly e-mail client, without Gmail support"
+arch=('i686' 'x86_64')
+url="http://sylpheed.sraoss.jp/en/"
+license=('GPL')
+depends=('gpgme' 'gtkspell' 'desktop-file-utils')
+makedepends=('compface' 'openssl')
+options=('!libtool')
+replaces=$_pkgname
+conflicts=$_pkgname
+provides=$_pkgname=$pkgver
+install="$_pkgname.install"
+source=("http://sylpheed.sraoss.jp/$_pkgname/v3.3/$_pkgname-$pkgver.tar.bz2"
+        'nonprism.patch')
+md5sums=('20442f81dbb4e7c59462360ad0bb1afb'
+         'e1bddc14962e607cdb899ec082660639')
+
+prepare() {
+  cd "$srcdir/$_pkgname-$pkgver"
+
+  # Remove Gmail support
+  patch -Np1 -i "$srcdir/nonprism.patch"
+}
+
+build() {
+  cd "$srcdir/$_pkgname-$pkgver"
+  ./configure --prefix=/usr \
+              --enable-ldap
+  make
+
+  # Build Attachment-Tool Plug-in
+  cd plugin/attachment_tool && make
+}
+
+package() {
+  cd "$srcdir/$_pkgname-$pkgver"
+  make DESTDIR="$pkgdir/" install
+
+  # Install Attachment-Tool Plug-in
+  cd plugin/attachment_tool
+  make DESTDIR="$pkgdir/" install-plugin
+}