remove nonprism suffix and add complex pkgrel on nonprism packages

1 files changed, 58 insertions, 0 deletions

diff --git a/nonprism/gthumb/PKGBUILD b/nonprism/gthumb/PKGBUILD
new file mode 100644
index 000000000..7e379542d
--- /dev/null
+++ b/nonprism/gthumb/PKGBUILD
@@ -0,0 +1,58 @@
+# $Id: PKGBUILD 213426 2014-05-23 22:54:51Z heftig $
+# Maintainer (Arch): Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
+# Contributor (Arch): Jan de Groot <jgc@archlinux.org>
+# Contributor (Arch): Tobias Kieslich <tobias@justdreams.de>
+# Maintainer: André Silva <emulatorman@parabola.nu>
+# Contributor: Márcio Silva <coadde@parabola.nu>
+
+pkgname=gthumb
+pkgver=3.2.8
+pkgrel=1.nonprism1
+pkgdesc="Image browser and viewer for the GNOME Desktop, without support for unsafe and dangerous for privacy protocols"
+arch=(i686 x86_64)
+license=(GPL)
+url="http://live.gnome.org/gthumb"
+replaces=(${pkgname}-nonprism)
+conflicts=(${pkgname}-nonprism)
+depends=(desktop-file-utils hicolor-icon-theme dconf librsvg clutter-gtk
+         gst-plugins-base-libs gsettings-desktop-schemas libwebp libsecret
+         libsoup webkitgtk json-glib)
+makedepends=(intltool libchamplain libopenraw exiv2 itstool brasero librsvg libopenraw liboauth docbook-xsl)
+optdepends=('libopenraw: read RAW files'
+            'exiv2: metadata support'
+            'libchamplain: map viewer'
+            'brasero: burn discs'
+            'liboauth: web albums')
+options=('!emptydirs')
+install=gthumb.install
+source=(http://ftp.gnome.org/pub/GNOME/sources/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.xz
+        nonprism.patch)
+sha256sums=('d600aba747af551540f3bbae8e8afa1cc308c658d911318c98fd4bf52ecd61b8'
+            '7706181514c9cfe0241329e9b14778dfa2797ddc1feb206b1cd9f07f9be31490')
+
+prepare() {
+  cd $pkgname-$pkgver
+  patch -Np1 -i $srcdir/nonprism.patch
+}
+
+build() {
+  cd $pkgname-$pkgver
+  
+  ./configure --prefix=/usr --sysconfdir=/etc \
+      --localstatedir=/var --disable-static \
+      --enable-libchamplain --enable-libopenraw
+  
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0 /g' -e 's/    if test "$export_dynamic" = yes && test -n "$export_dynamic_flag_spec"; then/      func_append compile_command " -Wl,-O1,--as-needed"\n      func_append finalize_command " -Wl,-O1,--as-needed"\n\0/' libtool
+
+  make
+}
+
+check() {
+  cd $pkgname-$pkgver
+  make check
+}
+
+package() {
+  cd $pkgname-$pkgver
+  make DESTDIR="$pkgdir" install
+}