[gst-plugins-bad]: upgrade to v1.16.2 (new split package)

1 files changed, 65 insertions, 30 deletions

diff --git a/libre/gst-plugins-bad/PKGBUILD b/libre/gst-plugins-bad/PKGBUILD
index 2784213e3..98b8299e2 100644
--- a/libre/gst-plugins-bad/PKGBUILD
+++ b/libre/gst-plugins-bad/PKGBUILD
@@ -3,50 +3,62 @@
 # Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
 # Contributor: Isaac David <isacdaavid@at@isacdaavid@dot@info>
 # Contributor: Márcio Silva <coadde@hyperbola.info>
+# Contributor: bill-auger <bill-auger@programmer.net>
 
-pkgname=gst-plugins-bad
-pkgver=1.16.0
-pkgrel=5
-pkgrel+=.par1
-pkgdesc="GStreamer Multimedia Framework Bad Plugins"
-pkgdesc+=", without nonfree faac support"
+# parabola changes and rationale
+# * removed support for non-free faac codec
+# * removed failing check() function (Failed to start up HTTP server)
+
+
+pkgbase=gst-plugins-bad
+pkgname=(gst-plugins-bad-libs gst-plugins-bad)
+pkgver=1.16.2
+pkgrel=10
+pkgrel+=.parabola1
+pkgdesc="GStreamer Multimedia Framework Bad Plugins, without nonfree faac support"
 url="https://gstreamer.freedesktop.org/"
 arch=(x86_64)
 arch+=(i686 armv7h)
 license=(LGPL)
-depends=(mjpegtools gst-plugins-base-libs curl chromaprint libmms faad2 celt libdca libdvdnav
-         libmodplug libgme wayland libofa openjpeg2 libwebp libsrtp gnutls sbc rtmpdump libgudev
-         libexif libdvdread libvdpau libmpeg2 wildmidi ladspa openal libusb vulkan-icd-loader
-         libfdk-aac soundtouch spandsp neon webrtc-audio-processing libdc1394 libmpcdec zvbi
-         openexr libbs2b libnice lcms2 bluez-libs glu srt aom x265 liblrdf libde265 zbar
-         gst-plugins-good)
-makedepends=(python gtk-doc git gobject-introspection gtk3 vulkan-headers vulkan-validation-layers
-             librsvg libtiger fluidsynth lilv meson)
-replaces=("${pkgname}-libre" "${pkgname}-parabola")
-conflicts=("${pkgname}-libre" "${pkgname}-parabola")
-_commit=5fde70bb63a1cbf6f734fb2429e74ffb53126217  # tags/1.16.0^0
+depends=(gst-plugins-base-libs orc libdrm libx11 libgudev libusb libvdpau)
+makedepends=(mjpegtools curl chromaprint libmms faad2 libdca libdvdnav
+             libmodplug libgme nettle libkate wayland libofa openjpeg2 libwebp
+             libsrtp sbc rtmpdump libexif libdvdread wildmidi ladspa openal
+             vulkan-icd-loader libfdk-aac soundtouch spandsp neon
+             webrtc-audio-processing libdc1394 libmpcdec zvbi openexr libbs2b
+             libnice lcms2 bluez-libs glu srt aom x265 liblrdf libde265 zbar
+             librsvg fluidsynth lilv lv2 gst-plugins-good python gtk-doc git
+             gobject-introspection vulkan-headers vulkan-validation-layers
+             wayland-protocols gtk3 meson)
+replaces=("${pkgbase}-libre" "${pkgbase}-parabola")
+conflicts=("${pkgbase}-libre" "${pkgbase}-parabola")
+options=(!emptydirs)
+_commit=a6f26408f74a60d02ce6b4f0daee392ce847055f  # tags/1.16.2^0
 source=("git+https://gitlab.freedesktop.org/gstreamer/gst-plugins-bad.git#commit=$_commit"
-        'gst-common::git+https://gitlab.freedesktop.org/gstreamer/common.git')
+        0001-vulkan-Drop-use-of-VK_RESULT_BEGIN_RANGE.patch)
 sha256sums=('SKIP'
-            'SKIP')
+            '0c6c51a371d8f381a2190280913cc41e06c17c25dbb1167043072003b3f0d338')
 
 pkgver() {
-  cd $pkgname
+  cd $pkgbase
   git describe --tags | sed 's/-/+/g'
 }
 
 prepare() {
-  cd $pkgname
+  cd $pkgbase
 
-  git submodule init
-  git config --local submodule.common.url "$srcdir/gst-common"
-  git submodule update
+  # Fix build with neon 0.31
+  git cherry-pick -n f10b424418e448211e3427a76fcd046e157ef0b7
 
-  NOCONFIGURE=1 ./autogen.sh
+  # Fix build with vulkan-headers 1.2.140
+  git apply -3 ../0001-vulkan-Drop-use-of-VK_RESULT_BEGIN_RANGE.patch
+
+  # Fix build with GCC 10
+  git cherry-pick -n a0cd455dd0e0375c6395fe732173225ea7e18562
 }
 
 build() {
-  arch-meson $pkgname build \
+  arch-meson $pkgbase build \
     -D directfb=disabled \
     -D faac=disabled \
     -D flite=disabled \
@@ -74,10 +86,33 @@ build() {
   ninja -C build
 }
 
-check() {
-  meson test -C build --print-errorlogs
-}
+package_gst-plugins-bad-libs() {
+  pkgdesc="${pkgdesc/plugins/libraries}"
 
-package() {
   DESTDIR="$pkgdir" meson install -C build
+
+  mkdir -p ext/lib/gstreamer-1.0
+  for _x in aom assrender bs2b bz2 chromaprint closedcaption colormanagement \
+            curl dashdemux dc1394 de265 dtls dtsdec faad fdkaac \
+            fluidsynthmidi gme hls kate ladspa lv2 mms modplug mpeg2enc mplex \
+            musepack neonhttpsrc ofa openal openexr openjpeg opusparse \
+            resindvd rsvg rtmp sbc smoothstreaming sndfile soundtouch spandsp \
+            srt srtp teletext ttmlsubs vulkan waylandsink webp webrtc \
+            webrtcdsp wildmidi x265 zbar; do
+    _x="lib/gstreamer-1.0/libgst${_x}.so"
+    mv "$pkgdir/usr/$_x" "ext/$_x"
+  done
+}
+
+package_gst-plugins-bad() {
+  depends=("gst-plugins-bad-libs=$pkgver" gst-plugins-good
+           aom libass libbs2b bzip2 chromaprint pango lcms2 curl libxml2
+           libdc1394 libde265 openssl libdca faad2 libfdk-aac fluidsynth
+           libgme nettle libkate liblrdf lilv libmms libmodplug mjpegtools
+           libmpcdec neon libofa openal openexr openjpeg2 opus libdvdnav
+           libdvdread librsvg rtmpdump sbc libsndfile soundtouch spandsp srt
+           libsrtp zvbi vulkan-icd-loader libxcb wayland libwebp libnice
+           webrtc-audio-processing wildmidi x265 zbar)
+
+  mv ext "$pkgdir/usr"
 }